Fortran 부 프로그램에서 지역적인(local) 배열을 선언하는 것이 가능하지만 잘 사용하지는 않는다. 보통 모든 배열은 주 프로그램에서 그 크기와 함께 선언하고 필요한 부 프로그램에 넘겨진다.
y := alpha * x + y
로 alpha는 scalar이고 x와 y는 vector이다. 이를 구현한 간단한 subroutine은 다음과 같다.
subroutine saxpy (n, alpha, x, y)
integer n
real alpha, x(*), y(*)
c
c Saxpy: Compute y := alpha*x + y,
c where x and y are vectors of length n (at least).
c
c Local variables
integer i
c
do 10 i = 1, n
y(i) = alpha*x(i) + y(i)
10 continue
c
return
end
여기서 새로운 것은 x(*) 와 y(*)의 선언문에서 asterisk (*)를 사용한 것이다. 이 표시는 x와 y는 길이가 임의적인 배열이라는 뜻이다. 이 것의 장점은 하나의 서브루틴으로 어떠한 길이의 vector도 다룰 수 있다는 것이다. Fortran은 call-by-reference를 사용하기에 sburoutine에서 추가로 memory 공간을 배정하기보다는 부르는 routine/program에서 전달된 배열 원소에 직접적으로 작용한다는 것을 기억하라. vector x와 y가 다른 프로그램에서 길이가 n 또는 그 이상으로 선언되었음을 획인하는 것은 프로그램하는 사람의 책임이다. A common error in Fortran 77에서 흔히 생기는 오류는 배열 밖의 원소를 사용하려고 할 때 발 생한다.
또 배열을 다음과 같이 선언할 수도 있다.
real x(n), y(n)
대부분의 프로그램머는 "실제 배열 길이"를 모른다는 것을 강조하기 위하여 asterisk (*)를 사용하기 좋아한다. 오래된 Fortran 77 프로그램에서는 다음과 같이 가변 길이 배열을 선언하기도 한다.
real x(1), y(1)
이는 배열의 길이가 1보다 클 때도 유요한 표현이다. 그러나 별로 좋은 표현은 아니기에 사용하지 말 것을 권한다.
subroutine matvec (m, n, A, lda, x, y)
integer m, n, lda
real x(*), y(*), A(lda,*)
c
c Compute y = A*x, where A is m by n and stored in an array
c with leading dimension lda.
c
c Local variables
integer i, j
c Initialize y
do 10 i = 1, m
y(i) = 0.0
10 continue
c Matrix-vector product by saxpy on columns in A.
c Notice that the length of each column of A is m, not n!
do 20 j = 1, n
call saxpy (m, x(j), A(1,j), y)
20 continue
return
end
언급하여야 할 점이 몇 개 있다. 첫째, 임의의 차원 m과 n에 대하여 가능하도록 일반적인 code를 만들었지만 아직도 matrix A의 leading 차원을 적어야만 한다.
가변 길이 선언 (*)은 배열의 마지막 차원에만 사용할 수 있다. 그 이유는 Fortran 77이 다차원 배열을 저장하는 방법 때문이다. (배열에 관한 내용 참조).
saxpy 연산으로 y = A * x를 계산할 때 A의 column이 필요하다. A의 j번째 column은 A(1:m,j)이다. 그러나 Fortran 77에서는 이러한 부배열을 나타내는 방법을 사용할 수 없다 (그러나 Fortran 90에서는 사용 가능하다). 따라서 column의 첫번째 원소 A(1,j)를 가리키는 pointer를 준비할 필요가 있다. (실제로는 pointer가 아니지만 pointer인 것 처럼 생각하면 도움이 된다.) 다음 memory에 이 column의 다음 원소가 있다는 것을 안다. saxpy subroutine에서는 A(1,j)를 vector의 첫번째 원소로 취급하고 이 vector가 matrix의 한 column일 수도 있다는 것은 알지 못하는 것이다.
마지막으로, m 행 n 열의 matrix에 관한 표시 방법을 따라야 한다. 즉 index i 는 행 index로 (1 to m), index j는 열 index (1 to n) 사용한다. 대부분의 선형 대수를 다루는 Fortran 프로그램에서는 이 표기 방법을 따르고 있어 code를 읽기 쉽다.
간단한 예를 살펴 보자. 또 다른 기본적인 vector 연산은 scaling, 즉 vector의 각 원소에 같은 상수를 곱하는 것이다. 다음은 이 연사을 하는 subroutine이다.
subroutine scale(n, alpha, x)
integer n
real alpha, x(*)
c
c Local variables
integer i
do 10 i = 1, n
x(i) = alpha * x(i)
10 continue
return
end
scale하고자하는 m x n matrix가 있다. 새 subroutine을 쓰는 대신에 vector를 matrix로 취급하고 subroutine scale을 사용할 수 있다. 간단하게는 다음과 같다.
integer m, n
parameter (m=10, n=20)
real alpha, A(m,n)
c Some statements here define A...
c Now we want to scale A
call scale(m*n, alpha, A)
이 예제는 A의 선언한 차원이 A에 저장된 실제 차원과 같기에 문제가 없다. 이것이 일반적으로 성립하지는 않는다. 때때로 leading dimension lda가 실제 차원 m과 다르기에 이를 올바르게 다루려면 주의하여야 한다. 다음은
subroutine scale을 사용하여 matrix에 상수를 곱하는 좀더 확실한 subroutine이다.
subroutine mscale(m, n, alpha, A, lda)
integer m, n, lda
real alpha, A(lda,*)
c
c Local variables
integer j
do 10 j = 1, n
call scale(m, alpha, A(1,j) )
10 continue
return
end
이것은 한 번에 한 column씩 곱하고 각 column의 처음 m개의 원소만 취급하기에 (다른 것은 변하지 않는다) m이 lda와 같지 않아도 된다.
integer nmax
parameter (nmax=40)
real A(nmax, nmax)
적당한 vector x와 y를 선언하고 다음과 같이 초기화 하라.
m=10, n=20, A(i,j) = i+j-2 for 1<=i<=m and 1<=j<=n,
x(j) = 1 for 1<=j<=n.
위에 주어진 matvec subroutine을 사용하여 y = A*x를 계산하라.
결과 y를 인쇄하라.